***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*May 27, 2020                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt RS1002FL A K
.param
+vc0 = 1.746e-10	 vc1 = 1.053e-11	 vc2 = 1.000e-0		
+vc3 = 4.341e-11	 vc4 = 6.455e-3
+tc1 = 1.351e-1		 tc2 = 3.201e-2		 tc3 = 2.051e-2		tc4 = 3.401e-2
+tc5 = 1.801e-2		 tc6 = 1.271e-2
.func ir0(v) {(vc0)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
.func ir1(v) {(vc1*v^vc2)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.func ir2(v) {(vc3*exp(vc4*v))*(1.0+tc5*(temp-25)*exp(tc6*(temp-25)))}
.func irexp(v) {ir0(v)+ir1(v)+ir2(v)}
g1 K A value = {irexp(v(K,A))}
d1 A K sbd
.model sbd d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 1.568e-12	   n = 1.063		  rs = 3.557e-2		ikf = 6.043e-2
+ibv = 0.1e-3		 nbv = 1	  	  bv = 220
***** capacitance parameter *****
+cjo = 4.125e-11  	   m = 3.045e-1		  vj = 3.602e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.019		 xti = 3
+trs1 = -1.871e-3	trs2 = -2.004e-6	tikf = 5e-3
.ends RS1002FL
*$
